<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<%
Option Explicit

Const Version="2.6"
%>

<!-- COPYRIGHT HEADER
 Simple Online Photo Catalog VBScript v<%=Version%>
 Author: Ivan Loire - www.iloire.com - ivan@iloire.com
 Copyright 2002-2004. All rights reserved.
 Script Homepage: http://www.iloire.com/vbscript/online_photo_catalog_vbscript.asp

 Licence:
	- GPL. You can use and distribute freely this code as long as you give the
 credits to the author.
 	- Removing or modifying the copyright header without written permission of the author
 is a violation of  the licence.

 If you would like to add comments or suggestions, rate this script or submit new layouts,
 go to the script homepage.
END COPYRIGHT HEADER -->

<%
'--------
'##############
'CONFIGURATION.

Const cPageTitle="Model gallery"  'Page title. Change it at your will.
Const cVirtualPath="images/" 'IMPORTANT: Set the images virtual folder (with the last "/")
Const cAdminEmail="info@aztecmodels.com" 'in order to notify administrator about new comments.

Dim cWritableXMLCommentsFile 'Physical folder where the xml comment files are going to be written.
cWritableXMLCommentsFile=Server.Mappath(cVirtualPath) & "\comments.xml"  'Value: a valid physical folder. Must end with "\"

'cosmetic
Const cMaxThumbnailsSize=100 ' Thumbnail's width. Values: a valid integer
Const cNumberPicturesPerRowDefault=2 'set the default number of thumbails per row.
Const cimgPlus="plus.gif"
Const cimgChildNode="child.gif"
Const cimgMinus="minus.gif"
Const cNumberRecentComments=7

'language
'I had took language configuration out, to make easier multilingual support
%>
<!--#include file="resources.txt" -->
<%

'funcionality
Const cShowEmptyFolders=true 'If a folder doesn't contain files inside, would it be displayed?
Const cImageExtensions=".jpg,.gif,.png" 'the system would considerar files with that extension as images
Const cAllowUserChangePicturePerRow=true 'allow visitor to change the number of pictures he visualize per row
Const cAllowUserEnterComments=true 'allow visitor to add comments to the pics. You will need write access permit to comments file!
Const cHideFoldersPattern="_vti_cnf"

'thumbnail generator
Const cUseThumbnailFile=false 'Values: true or false. Set to true if you are using a server page to create the thumbnail (if your server has .NET Framework installed)
Const cUseThumbnailFilePath="thumbnail.aspx" 'path to server page that will generate the thumbnail

'set here available sizes to display the big picture, separate by coma.
Const cAvailableThumbnailSizes="original,200,300,500,600"  ' "original" is a reserved word
Const cDefaultThumbnailSize="original"  'set value that would appear as 'default'


'Main page text
sub WriteMainText()
'write here whatever HTML you would like to add to the main page
%>
	<!--#include file="maintext.txt"-->
<%
end sub


'Image Copyright text(apply to every picture)
sub WriteCopyRightText()
%>
	<!--#include file="copyright.txt"-->
<%
end sub


'Parse here the picture name as you wish, to take certain characters out of the display name, for example
function ParsePictureName(filepath)
	Const maxPicNamesize=10
	Dim output
	output=fs.GetBaseName(filepath)
	output=replace(replace(output,"_"," "),"-"," ") 'change "_" for " ", "-" for " "
	if len(output)>maxPicNamesize then output=left(output,maxPicNamesize) + ".."
	ParsePictureName=output
end Function


'Do whatever you want then a visitor write a comment (send and email to the admin, for example)
sub OnCommentAdded(author,email,text,picturelink)
	'lets send an email using CDONTS (be sure you have installed it in your server)
	Dim objCDO
	Set objCDO = Server.CreateObject("CDONTS.NewMail")
	objCDO.To = cAdminEmail
	objCDO.From = cAdminEmail
	objCDO.Subject = "Simple online photo catalogue comment"
	objCDO.Body = "Author: " & author & vbcrlf & _ 
	"Email: " & email & vbcrlf &  _
	"Comments: " & text & vbcrlf & _
	"Picture: " & vbcrlf & picturelink
	objCDO.Send
	Set objCDO = Nothing
end sub

'END CONFIGURATION
'#################


'FUNCTIONS
'function to write formated output to response object.
sub prt(strValue)
	response.write(strValue) & Vbcrlf
end Sub


'get XML document from file or create a new one if it doesn't exist
function GetXmlObj()
	Dim objXML
	Set objXML = Server.CreateObject("Microsoft.XMLDOM")
	If objXML.load(cWritableXMLCommentsFile) = False Then
		 objXML.appendChild(objXML.createProcessingInstruction("xml","version=""1.0"" encoding=""utf-8"""))
		 objXML.appendChild(objXML.createElement("comments"))
	End If
	set GetXmlObj=objXML
end function


'BEGIN SEARCH ENGINE
'Show search engine form
sub DisplaySearch()
	prt cSearchPictures
	prt "<form method=post target=frm_bottom action=""" & strThispage & "?action=search"">"
	prt "<input type=text class=textbox name=search value=""" & request("search") & """><input type=submit class=button value=""" & cSearch & """>"
	prt "</form>"
End sub

'Do search
Sub DoSearch()
	if len(request("search")) then
			dim result,i
			result=split(searchPictures(cVirtualPath,request("search")),";")
			for i=0 to ubound(result) -1
					ShowResultSearchPicture(result(i))
			next
			if ubound(result)=-1 then prt cNoResultsFoundFor & " <strong><em>" & request("search") & "</em></strong>"
	end if
End Sub

'search engine
function searchPictures(Item, filter)
	Dim folder,subfolder,file
	set folder = fs.GetFolder(Server.MapPath(Item))
	For each subfolder in folder.SubFolders
		searchPictures= searchPictures & searchPictures(Item & subfolder.Name & "/",filter)
	next
	for each file in folder.Files
		if (len(filter)=0 or instr(1,file.Name,filter,1)>0) then searchPictures=searchPictures & Item & file.Name & ";"
	next
end function
'END SEARCH ENGINE


'Display recent comments
'IDEA: Eliram Haklay
Sub displayRecentComments ()
	Dim commentsList,objXML,comment,objXMLcomment,i,startPos,tempWriter
	Set objXML = GetXmlObj()
	set commentsList=objXML.selectNodes("/comments/comment") 'we could be using xPath with position()< cNumberRecentComments if we were using MSXML2.DOMDocument.4.0
	If commentsList.length > 0 Then
		startPos=commentsList.length - cNumberRecentComments
		If startPos<0 Then startPos=0
			For i = commentsList.length-1 to startPos step -1
				Set comment=objXML.childnodes(1).childnodes(i)
				Prt "<strong>" & cFileName & "</strong> " & comment.childnodes(4).text & "<br />"
				Prt "<div class=recentpicture>"
				ShowResultPicture(comment.childnodes(4).text)
				prt "</div>"
				Prt "<dl class=recentcomment>"
				FormatCommentsToDisplay(comment)
				prt "</dl><hr style=""clear:both;"">"
			Next
	End If
End Sub


'Show picture as result (used in search engine and recent comments display)
sub ShowResultPicture(path)
	if cUseThumbnailFile Then
		tempWriter=cUseThumbnailFilePath & "?ForceAspect=false&Height=" & cMaxThumbnailsSize & "&Width="& cMaxThumbnailsSize & "&image=" & Server.URLencode(path)
	else
		tempWriter=path
	End If

	prt "<center>"
	Prt "<a target=frm_bottom href=""?action=displayimage&item=" & Server.URLencode(path) & """>" &_
	"<img alt=""" & ParsePictureName(path) & """ border=0 width=""" & cstr(cMaxThumbnailsSize) & """ src="""& tempWriter & """ />" &_
	"</a> <br />"

	Prt "<a target=frm_bottom href=""?action=displayimage&item=" & Server.URLencode(path) & """ />"
	Prt cViewImage
	Prt "</a> - "

	Prt "<a target=frm_files href=""?action=displayfiles&item=" & Server.URLencode(fs.GetParentFolderName(path) & "/") & """>"
	Prt cViewFolder
	Prt "</a>"
	prt "</center>"
	Prt "</div>"
end sub


'format comment output from comment XML comment node
sub FormatCommentsToDisplay(comment)
			prt "<dt><span class=name>"
			If Len(comment.childnodes(1).text) then
				prt "<a href=""mailto:" & Server.HtmlEncode(comment.childnodes(1).text) & """>" & Server.HtmlEncode(comment.childnodes(0).text) & "</a>"
			else
				prt Server.HtmlEncode(comment.childnodes(0).text)
			end if
			prt "</span>, " & cOn &  " <span class=date>" & Server.HtmlEncode(comment.childnodes(3).text) & "</span> " & cSaid & ":</dt>"
			prt "<dd class=comments>" & replace(Server.HtmlEncode(comment.childnodes(2).text),chr(10),"<br />") & "</dd>"

end sub


'Show individual picture as search result
sub ShowResultSearchPicture(path)
	Dim objXml,commentsList,comment
	Prt "<strong>" & cFileName & "</strong> " & replace(path,request("search"),"<span class=marked>" & request("search") & "</span>",1,-1,1) & "<br />"
	Prt "<div class=recentpicture>"
	ShowResultPicture(path)
	prt "</div>"
	Set objXML = GetXmlObj()
	set commentsList=objXML.selectNodes("/comments/comment[path=""" & path & """]")
	if commentsList.length>0 then
		Prt "<div class=recentcomment>"
		for each comment in commentsList
			FormatCommentsToDisplay(comment)
			prt "<br />"
		next
		prt "</div>"
	end if
	prt "<hr style=""clear:both"" />"
end sub


'Gets "next" picture file name
'IDEA: Eliram Haklay
Function FindTheNext (FileName)
	Dim File,folder,foundFile,theNextFile
	Set folder = fs.GetFolder(Server.MapPath(fs.GetParentFolderName(FileName)))
	foundFile=0
	For each File in folder.Files
		If instr(1,cImageExtensions,fs.GetExtensionName(File.path),1)>0 then
			If foundFile=1 Then
				FindTheNext = File.Name
				foundFile=0
				Exit Function
			Else
				If File.Name=fs.GetFileName(FileName) Then
					foundFile=1
				End If
			End If
		End If
	Next
	FindTheNext=""
End Function


'Gets "previous" picture file name
'IDEA: Eliram Haklay
Function FindThePrev (FileName)
	Dim File,folder,foundFile,theNextFile
	Set folder = fs.GetFolder(Server.MapPath(fs.GetParentFolderName(FileName)))
	theNextFile=""
	For each File in folder.Files
		If instr(1,cImageExtensions,fs.GetExtensionName(File.path),1)>0 then
			If File.Name=fs.GetFileName(FileName) Then
				FindThePrev=theNextFile
				Exit Function
			Else
				theNextFile=File.Name
			End If
		End If
	Next
	FindThePrev=""
End Function


Sub UserCommentsEngine ()
	Dim link,commentsList,objXML,comment,objXMLcomment

	Set objXML = GetXmlObj()
	link="?action=displayimage&Item=" & Server.URLencode(request("Item"))

	Prt "<div class=comments id=visitor><h2>" & cVisitorComments &  "</h2>"

	Prt "<div class=body>"


	If len(request("text"))>0  then 'write
		Set objXMLcomment = objXML.createElement("comment")
		objXMLcomment.appendChild(objXML.createElement("author"))
		objXMLcomment.appendChild(objXML.createElement("email"))
		objXMLcomment.appendChild(objXML.createElement("text"))
		objXMLcomment.appendChild(objXML.createElement("date"))
		objXMLcomment.appendChild(objXML.createElement("path"))
		objXMLcomment.appendChild(objXML.createElement("image"))

		objXMLcomment.childNodes(0).text = request("author")
		objXMLcomment.childNodes(1).text = request("email")
		objXMLcomment.childNodes(2).text = request("text")
		objXMLcomment.childNodes(3).text = now()
		objXMLcomment.childNodes(4).text = request("item")
		
		'Save comment author details
		Session("author")=request("author")
		Session("email")=request("email")

		objXML.documentElement.appendChild(objXMLcomment.cloneNode(True))
		on error resume next
		objXML.save(cWritableXMLCommentsFile)
		if err.number<>0 then
			Prt ("<div class=error>" & cErrorSavingCommentTo & " <i>" & cWritableXMLCommentsFile & "</i>.<br><br>" & cErrorMessage & " " & err.Description & "</div>")
		else
			Call OnCommentAdded(request("author"),request("email"),request("text"),"http://" & Request.ServerVariables("server_name") & Request.ServerVariables("URL") & "?" & Request.querystring)
			Prt ("<div class=success>" & cCommentAdded & "</div>")
		end if
		on error goto 0

	   end if


	'read
	set commentsList=objXML.selectNodes("/comments/comment[path=""" & request("item") & """]")
	for each comment in commentsList
			prt "<dl>"
			FormatCommentsToDisplay(comment)
			prt "</dl>"
	Next

	'write form
	prt "<center>"
	prt "<form method=post action=""" & strThispage & link &"""><table border=0>"
	prt "<tr><td>" & cYourName & "</td><td><input class=textbox type=text name=author value="""& session("author") & """><br></td></tr>"
	prt "<tr><td>" & cYourEmail & "</td><td><input class=textbox type=text name=email value="""& session("email") & """><br></td></tr>"
	prt "<tr><td>" & cComments & "</td><td><textarea class=textbox name=text cols=30 rows=5></textarea></td></tr>"
	prt "<tr><td>&nbsp;</td><td><input class=button type=submit value=""" & cPostYourComments & """></td></tr></table>"
	prt "</form>"
	prt "</center>"

	Prt "</div></div>"

End Sub


Function GetComment (PictureName)
	'getting the text from the comment file (if exists)
	Dim fl, File
	fl=Server.MapPath(replace (picturename, fs.GetExtensionName(picturename),"txt"))
	If fs.FileExists(fl) then
		set File = fs.OpenTextFile(fl, 1)
		GetComment = File.ReadAll
		File.Close
	End If
	set File=nothing
End Function


'Create thumbnails output for a particular virtual path
Sub DisplayFiles(VirtualPath)
	' Read Comments file to see if there are any comments for this folder
	Dim commentsList,objXML,comment,objXMLcomment,foundComments,commentFiles,cArray,cA
	Dim File,Folder,iRow, FileName,nImages,output,i
	Set objXML = GetXmlObj()
	Set commentsList=objXML.childnodes(1).childnodes
	commentFiles=""
	foundComments=0
	for each comment in commentsList
		If fs.GetParentFolderName(comment.childnodes(4).text) + "/"= VirtualPath Then
			foundComments=foundComments+1
			commentFiles=commentFiles & "," & fs.GetFileName(comment.childnodes(4).text)
		End If
	Next
	cArray = Split(commentFiles, ",")
	Set folder = fs.GetFolder(Server.MapPath(VirtualPath))
	iRow=0
	nImages=0


	output=output & "<table cellpadding=0 cellspacing=0 border=0 class=files align=center width=""98%"">"
		For each File in folder.Files
		If instr(1,cImageExtensions,fs.GetExtensionName(File.path),1)>0 then
			nImages=nImages+1
			If iRow=0 then output=output & "<tr class=ThRow>"
			output=output & "<td valign=top align=center>"
			output=output & "<a target=frm_bottom href=""?action=displayimage&item=" & Server.URLencode(VirtualPath & File.Name) & """>"
			tempWriter=""
			if cUseThumbnailFile then tempWriter=cUseThumbnailFilePath & "?ForceAspect=false&Height=" & cMaxThumbnailsSize & "&Width="& cMaxThumbnailsSize & "&image="
			output=output & "<img alt=""" & ParsePictureName(File.path) & """ border=0 width=""" & cstr(cMaxThumbnailsSize) & """ src="""& tempWriter & VirtualPath & File.Name  & """>"
			output=output & "<br/> " & ParsePictureName(File.path) & "</a><br/>"
			if (fs.FileExists(replace(File.path, fs.GetExtensionName(File.path),"txt")))=true Then output=output & "<span class=AComments>" & cAComments & "</span>"
			For each cA in cArray
				If cA=File.Name Then
					output=output & "<span class=VComments>" & cVComments & "</span>"
					Exit For
				End If
			Next
			output=output & "</td>"
			If cint(iRow)=cint(session("picsperrow")-1) then
				iRow=0
				output=output & "</tr>"
			Else
				iRow=iRow+1
			End If
		End if
	Next
	output=output & "</table>"

	Prt "<div class=top>"
	Prt cCurrentFolder & " <b>" & Folder.name & "</b> <span class=P>[" & nImages & " " & cImagesShort & "] [" & foundComments & " " & cCommentsShort & "]</span>"
	if cAllowUserChangePicturePerRow then Prt"<form target=frm_files method=post action=""" & strThispage & "?action=displayfiles&item="& Server.URLencode(virtualpath) & """>" & cPicsPerRow & " <input name=picsperrow class=textbox type=text maxlength=3 size=2 value=""" & session("picsperrow") & """><input type=submit value="""& cChange & """ class=button></form>"
	Prt "</div>"

	if nImages= 0 then
		Prt "<br><p>" & cThisFolderHasNoImages & "</p>"
	else
		Prt output
	end if

	Set folder=nothing
End Sub


'get subfolders from folder (recursive)
Sub DisplaySubFolders(Item)
	Dim subfolder,folder, parentfolder,linktext, preHtml, nImages, File
	set folder = fs.GetFolder(Server.MapPath(Item))
	If folder.subfolders.count > 0  then
			Prt "<ul>"
			For each subfolder in folder.SubFolders
				if instr(1,subfolder.name ,cHideFoldersPattern,1)= 0 then 
					'counting number of valid images in current folder
					nImages=0
					For each File in subfolder.Files											
						If instr(1,cImageExtensions,fs.GetExtensionName(File.path),1)>0 then nImages=nImages+1
					Next

					preHtml="<img src=""" & cimgChildNode & """>"
					IDcounter=IDcounter+1
					linktext=" <a onclick=""SetDisplay('" & IDcounter & "','','"  & cimgMinus & "');"" target=frm_files href=""?action=displayfiles&item="& Server.URLencode(Item & subfolder.Name) & "/"">" & subfolder.name &"</a>"
					if (subfolder.SubFolders.Count > 0) or (nImages > 0) or cShowEmptyFolders=true then
						tempWriter=""
						if nImages > 0 then
							tempWriter="<span class=S1> (" & nImages & " " & cImagesShort & ", " & Round(subfolder.Size/1024) & " Kb.)</span>"
						end if
						if subfolder.SubFolders.count > 0 then
							preHtml = "<a href=""Javascript:void(0)"" onclick=""ToogleDisplay(" & IDcounter & ");"">"
							preHtml = preHtml + "<img border=0 id=""i" & IDCounter & """ src=""" & cimgPlus & """></a>"
							tempWriter=tempWriter & "<span class=S> [" & subfolder.SubFolders.count & " " & cSub & "]</span>"
						elseif subfolder.Files.Count = 0 then
							If tempWriter="" Then
								tempWriter=" " & cEmpty
							End If
						end if
						Prt "<li>" & preHtml & linktext  &  tempWriter & "<div style=""display:none"" id=""l" & IDcounter & """>"
						DisplaySubFolders(Item & subfolder.Name &"/")
						Prt "</div>"
					end if
				end if
			Next
			Prt "</ul>"
	end if
End Sub


Sub CreateFramesBody()
%>
<frameset rows=25,* frameborder=yes bordercolor="#f5f5f5" border=0>
	<frame name=frm_header scrolling=yes src="?action=title">
	<frameset cols="250,*" bordercolor="#f5f5f5" frameborder=no border=1>
		<frameset rows="30%,*,60" frameborder=yes bordercolor="#f5f5f5" border=1>
			<frame name=frm_folders scrolling=Auto src="?action=displayfolders">
			<frame name=frm_files src="?action=empty">
			<frame name=frm_search scrolling=Auto src="?action=search">
		</frameset>
		<frame name="frm_bottom" scrolling=Auto src="?action=start">
	</frameset>
</frameset>
<%
End Sub


sub displayMainImage()
	tempWriter=""
	'create resize image select box
	Dim selectHtml,i,theNext,thePrev
	selectHtml="<select name=targetimgsize>"
	for i=0 to ubound(sizeValues)
		if (cstr(sizeValues(i)) = "original") and (cstr(session("targetimgsize"))=cstr(sizeValues(i))) then 'original item and current value
			selectHtml=selectHtml& "<option selected value=""original"">original</option>"
		elseif cstr(sizeValues(i)) = "original" then
			selectHtml=selectHtml& "<option value=""original"">original</option>"
		elseif cstr(session("targetimgsize"))=cstr(sizeValues(i)) then  'current one
			selectHtml=selectHtml& "<option selected value=""" & sizeValues(i) & """>" & sizeValues(i) & "px</option>"
		else
			selectHtml=selectHtml& "<option value=""" & sizeValues(i) & """>" & sizeValues(i) & "px</option>"
		end if
	next
	selectHtml=selectHtml & "</select>"
	'end select box creation

	if cUseThumbnailFile and cstr(session("targetimgsize"))<>"original" then tempWriter=cUseThumbnailFilePath & "?ForceAspect=False&Width=" & session("targetimgsize") & "&Height=" & session("targetimgsize") & "&image="

	Prt "<center>"
	if cUseThumbnailFile then Prt "<form method=post action=""" & strThispage & "?action=displayimage&item=" & Server.URLencode(request("item")) &  """>" & cSetMaximumsize & " " & selectHtml & "<input type=submit value=""" & cChange & """ class=button></form>"

	Prt "<div class=MainImage>"
		Prt "<div class=MainImageDim>"
			Prt "<table width=100% border=0 cellpadding=0 cellspacing=0><tr><td>"
			thePrev=FindThePrev (request("item"))

			If len(thePrev) Then Prt "<a target=frm_bottom href=""?action=displayimage&item=" & Server.URLencode(fs.GetParentFolderName(request("item")) & "/" & thePrev) & """><b>" & cPrevPicText & "</b></a>"

			Prt "</td><td align=center>"
			Prt cFileName & "<b>" & fs.GetFilename(request("item")) & "</b>"
			Prt "</td><td align=right>"
			theNext=FindTheNext (request("item"))

			If len(theNext) Then Prt "<a target=frm_bottom href=""?action=displayimage&item=" & Server.URLencode(fs.GetParentFolderName(request("item")) & "/" &  theNext) & """><b>" & cNextPicText & "</b></a>"
			Prt "</td></tr></table>"
		Prt "</div>"

		Prt ("<img alt=""" & fs.GetFilename(request("item")) & """ src=""" & tempWriter &  request("item") & """>")

		WriteCopyRightText()

		'comments
		tempWriter=GetComment (request("item"))
		if len(tempWriter)>0 then Prt "<div class=comments id=autor><h2>" & cAuthorComments & "</h2><div class=body>" & tempWriter & "</div></div>"
		if cAllowUserEnterComments then Call UserCommentsEngine()
	Prt "</div>"
	Prt "</center>"

end sub

'END FUNCTIONS


'MAIN

'On error resume next 'comment this line for debugging proposes

Dim fs
Set fs = CreateObject("Scripting.FileSystemObject")

Dim strThispage 'important to avoid 405 errors in "post"
strThispage= Request.ServerVariables ("SCRIPT_NAME")

Dim sizeValues
sizeValues = split(cAvailableThumbnailSizes,",") 'converting valid image values to array

Dim tempWriter 'use to store temporal values along the script
Dim IDcounter 'to assing unique ID's
IDcounter=0


if isnumeric(request("picsperrow")) and len(request("picsperrow")) > 0 then session("picsperrow")=cint(request("picsperrow"))
if not isnumeric(session("picsperrow")) or len(session("picsperrow"))=0 then session("picsperrow")=cNumberPicturesPerRowDefault

if len(request("targetimgsize")) > 0 then session("targetimgsize")=request("targetimgsize")
if len(session("targetimgsize"))=0 then session("targetimgsize")=cDefaultThumbnailSize

%>
<html>
<head>
	<title>Aztec Gallery</title>
	<link rel="stylesheet" href="online_photo_catalog_vbscript.css" type="text/css">
	<meta http-equiv="Content-Type" content="text/html; charset=UTF-8">
	<script language=javascript>

	function SetDisplay(elementid,displayvalue,imgsrc){
		if (document.getElementById('i' + elementid) !=null) document.getElementById('i' + elementid).src=imgsrc;
		document.getElementById('l' + elementid).style.display=displayvalue;
	}


	function ToogleDisplay(elementid){
		//alert(document.getElementById(elementid).style.display);
		if (document.getElementById('l' + elementid).style.display=='none'){ //it is contracted
			SetDisplay(elementid,'','<%=cimgMinus%>');
		}
		else{
			SetDisplay(elementid,'none','<%=cimgPlus%>');
		}
	}
	</script>
</head>
<%

Select case request("action")
  case "displayfolders"
	Prt("<body class=folders>")
	DisplaySubFolders(cVirtualPath)
	Prt("</body>")
  case "displayfiles"
	Prt("<body class=files>")
	Call DisplayFiles(request("item"))
	Prt("</body>")
  Case "recent"
	Prt("<body class=image>")
	displayRecentComments
	Prt("</body>")
  case "title"
	Prt("<body class=title>")
	Prt("<div style=""float:right"">")
	If cNumberRecentComments > 0 Then Prt("<a target=frm_bottom href=""" & strThispage & "?action=recent"">" & cNumberRecentComments & " " & cRecentComments & "</a> - ")
	Prt"<a target=frm_bottom href=""" & strThispage & "?action=start"">" & cGalleryHome & "</a> - "
	prt "</div>"
	Prt "<strong>" & cPageTitle & "</strong>"
	Prt "</body>"
  case "start"
	Prt "<body>"
	WriteMainText()
	Prt("</body>")
  case "empty"
  case "search"
  	Prt("<body class=image>")
  	displaysearch
  	dosearch
	Prt("</body>")
  case "displayimage"
	Prt "<body class=image>"
	DisplayMainImage
'	response.write "http://" & Request.ServerVariables("server_name") & Request.ServerVariables("URL") & "?" & Request.querystring
	Prt "</body>"
  case else
	CreateFramesBody
End select


Set fs=nothing
if err then
	Prt "<p class=error>Error: " & err.description + ".</p>"
end if
%>

</html>